DateTimePicker внутри DBGrid

Давайте посмотрим, как улучшить DBGrid.

Давайте начнем с создания простого приложения.

Сначала мы должны поместить TDateTimePicker на форму. Измените его имя на DateTimePicker и установите свойство Visible на False.

Как только Вы положите на форму DBGrid и установите связь с базой данных, отобразятся записи полей. Одно из полей, допустим имеет значение даты и имеет имя DateAdded.

Сначала мы должны удостовериться, что TDateTimePicker перемещен и установлен по размеру поля, в котором отображается DateAdded:

procedure TForm1.DBGrid1DrawColumnCell
  (Sender: TObject;
   const Rect: TRect;
   DataCol: Integer;
   Column: TColumn;
   State: TGridDrawState);
begin
  if (gdFocused in State) then
  begin
    if (Column.Field.FieldName = 'DateAdded') then
    with DateTimePicker do
    begin
      Left := Rect.Left + DBGrid1.Left + 1;
      Top := Rect.Top + DBGrid1.Top + 1;
      Width := Rect.Right - Rect.Left + 2;
      Width := Rect.Right - Rect.Left + 2;
      Height := Rect.Bottom - Rect.Top + 2;

      Visible := True;
    end;
  end
end;

Затем, когда мы покидаем ячейку, мы должны скрыть TDateTimePicker:

procedure TForm1.DBGrid1ColExit(Sender: TObject);
begin
  if DBGrid1.SelectedField.FieldName = 'DateAdded' then
    DateTimePicker.Visible := False
end;

Затем, обратите внимание, что в режиме редактирования все нажатия клавиш, которые поступают к DBGrid, мы должны удостовериться, что они поступают к TDateTimePicker. Прежде всего, это касается клавиши TAB для перемещения к другой ячейке.

procedure TForm1.DBGrid1KeyPress
(Sender: TObject; var Key: Char);
begin
  if (key = Chr(9)) then Exit;

  if (DBGrid1.SelectedField.FieldName = 'DateAdded') then
  begin
    DateTimePicker.SetFocus;
    SendMessage(DateTimePicker.Handle, WM_Char, word(Key), 0);
  end;
end;

И нужно добавить еще два события: перевести набор данных в режим редактирования, когда пользователь открывает календарь и мы должны назначить значение даты, которая была выбрана в TDatePickerTime полю DateAdded. Нужно обработать два события OnDropDown и OnChange:

procedure TForm1.DateTimePickerChange(Sender: TObject);
begin
  if DBGrid1.DataSource.State in [dsEdit, dsInsert] then
    ADOTable1DateAdded.Value := DateTimePicker.DateTime;
end;

procedure TForm1.DateTimePickerDropDown(Sender: TObject);
begin
  DBGrid1.DataSource.Edit;
end;

Вот и все!